^(.+)@(.+)$

^[\w.!#$%&'*+\/=?^_`{|}~-]+@[\w-]+(?:\.[\w-]+)*$
^(?:[\w!#$%&'*+\/\-=?^`{|}~]+(?:\.[\w!#$%&'*+\/\-=?^`{|}~]+)*)@(?:[a-zA-Z]+[a-zA-Z0-9-]*[a-zA-Z0-9](?:\.[a-zA-Z]+[a-zA-Z0-9-]*[a-zA-Z0-9])*(?:\.[a-zA-Z0-9]+))$

address = mailbox                                           ; one addressee
          ;または
          phrase ":" [#mailbox] ";"                         ; named list

mailbox = local-part "@" domain                             ; simple address
          ;または
          phrase "<" [route] local-part "@" domain ">"      ; name & addr-spec

route       =  1#("@" domain) ":"                           ; path-relative
local-part  =  word *("." word)                             ; uninterpreted 大文字小文字を区別しない
domain      =  sub-domain *("." sub-domain)
sub-domain = 1*<any CHAR except(除外する) specials, SPACE and CTLs>
             ; または
             domain-literal
domain-literal = "[" *(dtext / quoted-pair) "]"             ; DOMAIN-LITERALSの使用はあまり薦められません。
dtext = <any CHAR excluding(除く) "[",                        ; => may be folded
        "]", "\" & CR, & including(を含む) linear-white-space>

addr-spec   =  local-part "@" domain                        ; global address
domain-ref = 1*<any CHAR except(除外する) specials, SPACE and CTLs>
group = phrase ":" [#mailbox] ";"
quoted-pair = "\" CHAR                                      ; 任意の文字を引用できます
route-addr = "<" [route] addr-spec ">"
specials =  ()<>@,;:\".[] ; 単語内で使用するには、quoted-stringで囲まれた文字列でなければなりません。

# 先頭に「.」がある
.localPart@domain.co.jp
# 「@」の直前に「.」がある
localPart.@domain.co.jp
# ローカル部に「.」が連続している
localPart..@domain.co.jp
local..Part@domain.co.jp
# 半角英数字と「.!#$%&‘*+–/=?^_{|}~」以外を使っている
local[Part@domain.co.jp
local@Part@domain.co.jp

<domain> ::= <subdomain> | " " ;ドメイン名には大文字も小文字も許されるが、それには重要な違いがないことに注意してほしい。つまり、同じつづりで大文字・小文字の異なる二つの名前は同じ物として扱われるということである。
<subdomain> ::= <label> | <subdomain> "." <label>
<label> ::= <letter> [ [ <ldh-str> ] <let-dig> ] ;ラベルは ARPANET のホスト名の規則にしたがわなければならない。ラベルは文字で始まり、文字または数字で終わり、間には文字・数字・ハイフンだけが含まれなければならない。ラベルの長さにも制約があり、63 文字以下でなければならない。
<ldh-str> ::= <let-dig-hyp> | <let-dig-hyp> <ldh-str>
<let-dig-hyp> ::= <let-dig> | "-"
<let-dig> ::= <letter> | <digit>
<letter> ::= 大文字の A から Z と小文字の a から z の、アルファベット52 文字の内の任意の一文字
<digit> ::= 0 から 9 までの 10 個の数字の内の任意の一文字

IPv4-address-literal  = Snum 3("."  Snum)
IPv6-address-literal  = "IPv6:" IPv6-addr
General-address-literal  = Standardized-tag ":" 1*dcontent
Standardized-tag  = Ldh-str
                  ; Standardized-tag はスタンダードトラック RFC に                  ; おいて規定され、IANA に登録されなければならない
                  ; (MUST)

dcontent       = %d33-90 / ; Printable US-ASCII
               %d94-126 ; excl. "[", "\", "]"

Snum           = 1*3DIGIT ; 0 ～ 255 までの 10 進整数値を表す
IPv6-addr      = IPv6-full / IPv6-comp / IPv6v4-full / IPv6v4-comp
IPv6-hex       = 1*4HEXDIG ;HEXDIG = DIGIT / "A" / "B" / "C" / "D" / "E" / "F"小文字の "a", "b", "c", "d", "e", "f"もOKなので[1-9a-fA-F]的な感じ by RFC2234のCore Rules
IPv6-full      = IPv6-hex 7(":" IPv6-hex)
IPv6-comp      = [IPv6-hex *5(":" IPv6-hex)] "::"
               [IPv6-hex *5(":" IPv6-hex)] ; "::" は、値ゼロの 16 ビットグループが少なくとも2 つあることを表す。"::" に加えて高々 6 グループが現れる可能性がある。
;IPv4 マップ式 IPv6 アドレス------------------------------------------------------------
IPv6v4-full    = IPv6-hex 5(":" IPv6-hex) ":" IPv4-address-literal
IPv6v4-comp    = [IPv6-hex *3(":" IPv6-hex)] "::"
               [IPv6-hex *3(":" IPv6-hex) ":"]
               IPv4-address-literal ; "::" は、値ゼロの 16 ビットグループが少なくとも2 つあることを表す。"::" と IPv4-address-literalとに加えて高々 4 グループが現れる可能性がある。